project(demodinmarsat)

set(demodinmarsat_SOURCES
    inmarsatdemod.cpp
    inmarsatdemodsettings.cpp
    inmarsatdemodbaseband.cpp
    inmarsatdemodsink.cpp
    inmarsatdemodplugin.cpp
    inmarsatdemodwebapiadapter.cpp
)

set(demodinmarsat_HEADERS
    inmarsatdemod.h
    inmarsatdemodsettings.h
    inmarsatdemodbaseband.h
    inmarsatdemodsink.h
    inmarsatdemodplugin.h
    inmarsatdemodwebapiadapter.h
)

include_directories(
    ${CMAKE_SOURCE_DIR}/swagger/sdrangel/code/qt5/client
    ${INMARSATC_INCLUDE_DIR}
)

if(NOT SERVER_MODE)
    set(demodinmarsat_SOURCES
        ${demodinmarsat_SOURCES}
        inmarsatdemodgui.cpp
        inmarsatdemodgui.ui
    )
    set(demodinmarsat_HEADERS
        ${demodinmarsat_HEADERS}
        inmarsatdemodgui.h
    )

    set(TARGET_NAME ${PLUGINS_PREFIX}demodinmarsat)
    set(TARGET_LIB "Qt::Widgets")
    set(TARGET_LIB_GUI "sdrgui")
    set(INSTALL_FOLDER ${INSTALL_PLUGINS_DIR})
else()
    set(TARGET_NAME ${PLUGINSSRV_PREFIX}demodinmarsatsrv)
    set(TARGET_LIB "")
    set(TARGET_LIB_GUI "")
    set(INSTALL_FOLDER ${INSTALL_PLUGINSSRV_DIR})
endif()

if(NOT Qt6_FOUND)
    add_library(${TARGET_NAME} ${demodinmarsat_SOURCES})
else()
    qt_add_plugin(${TARGET_NAME} CLASS_NAME InmarsatDemodPlugin ${demodinmarsat_SOURCES})
endif()

if(NOT BUILD_SHARED_LIBS)
    set_property(GLOBAL APPEND PROPERTY STATIC_PLUGINS_PROPERTY ${TARGET_NAME})
endif()

if(DEFINED INMARSATC_DEPENDS)
    add_dependencies(${TARGET_NAME} ${INMARSATC_DEPENDS})
endif()

target_link_libraries(${TARGET_NAME} PRIVATE
    Qt::Core
    ${TARGET_LIB}
    sdrbase
    ${TARGET_LIB_GUI}
    ${INMARSATC_LIBRARIES}
)

install(TARGETS ${TARGET_NAME} DESTINATION ${INSTALL_FOLDER})

# Install debug symbols
if (WIN32)
    install(FILES $<TARGET_PROPERTY:${TARGET_NAME},RUNTIME_OUTPUT_DIRECTORY>/${TARGET_NAME}stripped.pdb CONFIGURATIONS Release DESTINATION ${INSTALL_FOLDER} RENAME ${TARGET_NAME}.pdb )
    install(FILES $<TARGET_PDB_FILE:${TARGET_NAME}> CONFIGURATIONS Debug RelWithDebInfo DESTINATION ${INSTALL_FOLDER} )
endif()
